>source

요약 탭으로 데이터를 가져 오는 큰 시트 세트가 있습니다. 나는 몇 가지 공식을 가지고 있는데 그 중 대부분은 작동하지만 일부는 작동하지 않으며 이유를 알 수 없습니다. 이 공식은 훌륭하게 작동합니다.

=index(importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Aj:$aj"),
match($A9&$B9&$C9&$D9&$I9&$N9,importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$a")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$t:$t")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Ab:$ab")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$b:$b")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$h:$h")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$n:$n"),0),1)

이상하게도 "일치"부분 자체에서 오류가 발생합니다 (일치가 없음).

=match($A9&$B9&$C9&$D9&$I9&$N9,importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$a")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$t:$t")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Ab:$ab")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$b:$b")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$h:$h")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$n:$n"),0)

그리고 큰 문제는이 공식이 "일치"부분 때문에 오류를 던진다는 것입니다.

=iferror(if(hlookup(D9&" ROYALTY FINAL",importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$DB"),
match($A9&$B9&$C9&$D9&$I9&$N9,importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$a")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$t:$t")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Ab:$ab")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$b:$b")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$h:$h")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$n:$n"),0),FALSE)=0,,
hlookup(D9&" ROYALTY FINAL",importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$DB"),
match($A9&$B9&$C9&$D9&$I9&$N9,importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$a")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$t:$t")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Ab:$ab")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$b:$b")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$h:$h")&
importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$n:$n"),0),FALSE)),)

이것은 개인 시트 세트 (및 수십 개의 상호 연결 시트 포함)이므로 공유 할 수는 없지만 오류를 재현하는 샘플을 만들었습니다 (아래).하지만 실제로 핵심 문제는 "일치"가 인덱스 수식이지만 자체적으로는 아니며 hlookup 수식 내에는 없습니다. 방금 일치 부분을 복사 했으므로 특정 상황에서만 작동하지 않는 이유를 알 수 없습니다. 누구든지 수식에서 오류를 볼 수 있습니까? 아니면 왜 작동하지 않는지에 대한 의혹이 있습니까?

덧붙여서, 도우미 탭에서 먼저 데이터를 가져온 다음이 수식을 사용했습니다 (연결을 사용하여 테스트하기도 함).

=hlookup(D9&" ROYALTY FINAL",TEMP!$A:$DB,match(concatenate($A9,$B9,$C9,$D9,$I9,$N9),TEMP!$A:$A&TEMP!$T:$T&TEMP!$AB:$AB&TEMP!$B:$B&TEMP!$H:$H&TEMP!$N:$N,0),FALSE)

하지만 여전히 같은 오류가 발생합니다 ...

필요한 부분을 다시 만들었고 오류가 여기에 있습니다. 문제가있는 시트는 다음과 같습니다.https://docs.google.com/spreadsheets/d/1nH144yPYyQZ0r1KYCjiNM8uRjPlS2Ziv6uyWfQrFrcQ/edit?usp=sharing

오류/샘플은 Y, Z 및 AB 열의 "COMMISSIONS"탭에 있습니다.

데이터를 가져 오는 시트는 다음과 같습니다.https://docs.google.com/spreadsheets/d/1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw/edit?usp=sharing


  • 답변 # 1

    가능한 답을 하나 찾았지만 어떤 결과를 기대 하시는지 잘 모르겠으므로 확신 할 수 없습니다. 현재 오류를 표시하는 Commissions에서 AB8 셀을 선택하고 Ctrl-Shift-Enter를 눌러 배열 수식으로 만들면 작동하는 것 같습니다. 앰퍼샌드를 사용하는 연결이 여러 IMPORTRANGE 문의 첫 번째 행에서만 작동하기 때문이라고 생각합니다 (긍정적이지 않음). 수식에서 일치하는 부분을 제거하고 다음과 같이하여이를 테스트합니다.

    ={ 
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$A:$a")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$t:$t")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$Ab:$ab")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$b:$b")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$h:$h")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$n:$n")}
    
    

    이것은 내 테스트에서 한 행만 반환합니다.

    그러나 ARRAYFORMULA를 추가하면 전체 속성 목록이 다시 나타납니다.

    이것이 도움이되는지 알려주십시오. 당신이 물어 본 다른 질문들을 볼게요 ...

    최신 정보:

    이것이 효과가 있다면 전체 열을 채우기 위해 다음과 같이 향상시킬 수 있습니다. AB8 셀에서 다음을 시도하십시오.

    = ArrayFormula(match($A8:A&$B8:B&$C8:C&$D8:D&$I8:I&$N8:N,
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$A:$A")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$t:$t")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$Ab:$ab")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$b:$b")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$h:$h")&
    importrange("1kNPtrBhRZxaboIddTM0hGnwJva02hMaKO-67F1FAtUw","TEAM SALES!$n:$n"),0))
    
    

    해당 셀을 병합 해제하면 AB3에 복사 할 수 있습니다.

  • 답변 # 2

    위의 완벽한 답변을 받기 전에 해결 방법을 선택했습니다. 비슷한 문제가있는 사람에게 도움이되기를 바랍니다. 문제는 HLOOKUP에있는 것 같습니다 (그리고 VLOOKUP에도있을 것이라고 가정합니다). 나는이 질문에 영감을 받아 HLOOKUP이 오류를 던지기가 너무 빨라 공식을 통해 작동 할 수 없다고 생각했습니다. 따라서 해결 방법은 인덱스/일치 (행과 열 모두 일치)를 사용하는 것입니다. 다음은 누군가 미래에이 문제가 발생할 경우를 대비하여 대체 된 공식 중 하나입니다.

    =iferror(index(importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$DB"),
    match($A3&$B3&$C3&$D3&$I3&$N3,importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$A:$a")&
    importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$t:$t")&
    importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$Ab:$ab")&
    importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$b:$b")&
    importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$h:$h")&
    importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$n:$n"),0),
    match(D3&" ROYALTY FINAL",importrange("1HprNdu3RgOimFFkyqp5k3pC79m-YubH0jtT3jKgDxzU","TEAM SALES!$1:$1"),0)),)
    
    

관련 자료

  • 이전 swing - 자바 - 구성 요소를 수평으로 중앙에 배치하고 수직으로 쌓는 방법은 무엇입니까?
  • 다음 html - 자바 스크립트 유효성 검사 후 요소 표시