CSV 문자열을 TSQL의 테이블로 변환하는 가장 간결한 방법은 무엇입니까?

여기에서 내 대답보기

그러나 기본적으로 당신은 :

DB에서이 함수를 생성하십시오 :

CREATE FUNCTION dbo.Split(@origString varchar(max), @Delimiter char(1))     
returns @temptable TABLE (items varchar(max))     
as     
begin     
    declare @idx int     
    declare @split varchar(max)     
    select @idx = 1     
        if len(@origString )<1 or @origString is null  return     
    while @idx!= 0     
    begin     
        set @idx = charindex(@Delimiter,@origString)     
        if @idx!=0     
            set @split= left(@origString,@idx - 1)     
        else     
            set @split= @origString
        if(len(@split)>0)
            insert into @temptable(Items) values(@split)     
        set @origString= right(@origString,len(@origString) - @idx)     
        if len(@origString) = 0 break     
    end 
return     
end

그런 다음 함수를 호출하고 분할하려는 문자열을 전달하십시오.

Select * From dbo.Split(@roles, ',')

SQL Server 호환성 수준 130을 사용하는 경우 STRING_SPLIT 기능이 현재 가장 간결한 방법입니다.

참조 링크 : https://msdn.microsoft.com/en-gb/library/mt684588.aspx

사용법 :

SELECT * FROM string_split('Pub,RegUser,ServiceAdmin',',')
RESULT:
value
-----------
Pub
RegUser
ServiceAdmin

옵션에 대한 자세한 설명은 다음과 같습니다.

SQL Server의 배열 및 목록

SQL Server의 기본 제공 XML 구문 분석을 사용하는 것도 옵션입니다. 물론 이것은 RFC-4180 호환 CSV의 모든 미묘한 차이를 반영합니다.

-- Given a CSV string like this:
declare @roles varchar(800)
select  @roles = 'Pub,RegUser,ServiceAdmin'
-- Here's the XML way
select split.csv.value('.', 'varchar(100)') as value
from (
     select cast('<x>' + replace(@roles, ',', '</x><x>') + '</x>' as xml) as data
) as csv
cross apply data.nodes('/x') as split(csv)

string_split 를 사용하여 SQL 2016+를 사용하는 경우  더 나은 방법이지만 SQL 2016 이전에이 작업을 수행하는 일반적인 방법입니다.

BULK INSERT를 사용하면 csv 파일을 SQL 테이블로 가져올 수 있습니다-

http://blog.sqlauthority.com/2008/02/06/sql-server-import-csv-file-into-sql-server-using-bulk-insert-load-comma-delimited-file-into -sql-server/